Cara mengetahui tanggal lahir dari NIK

Setiap penduduk Indonesia memiliki Nomor Induk Kependudukan (NIK) yang bersifat tetap dan berlaku seumur hidup sesuai dengan Undang-Undang Nomor 23 Tahun 2006 tentang Administrasi Kependudukan.

NIK tersebut terdiri dari 16 digit angka-angka dan dapat kita lihat pada Kartu Keluarga (KK), Kartu Tanda Penduduk (KTP), dan juga dokumen-dokumen penting lainnya.

Lalu, apakah arti 16 digit angka-angka pada NIK tersebut? Berikut penjelasannya sehingga kita dapat membaca dan memahaminya.

Misalkan 16 digit angka-angka tersebut kita tuliskan menjadi PPKKCC-DDMMYY-ABXZ, maka:

6 digit pertama (PPKKCC)

6 digit pertama adalah kode kecamatan di mana NIK pertama kali didaftarkan, di mana PP merupakan kode provinsi, KK merupakan kode kabupaten/kota dalam provinsi PP, dan CC merupakan kode kecamatan dalam kabupaten/kota KK.

Kode-kode ini adalah kode yang ditetapkan oleh Kementerian Dalam Negeri.
(Untuk melihat kode kecamatan yang ada di seluruh wilayah Jabodetabek, silakan klik di sini)

6 digit kedua (DDMMYY)

6 digit kedua adalah tanggal lahir pemilik NIK dalam format dua digit hari, dua digit bulan, dan dua digit tahun.

Dikarenakan tidak ada kode jenis kelamin dalam NIK, maka untuk membedakan penduduk laki-laki dan penduduk perempuan, untuk penduduk perempuan ditambahkan angka 40 pada tanggal lahir.

4 digit ketiga (ABXZ)

4 digit ketiga adalah nomor urut atau nomor unik yang diberikan kepada pemilik NIK untuk orang-orang yang memiliki tanggal lahir dan jenis kelamin yang sama pada satu kecamatan yang sama, sehingga tidak ada penduduk yang memiliki NIK yang sama.

Contoh:

Seseorang penduduk yang lahir pada tanggal 17 Agustus 1945 dan terdaftar pertama kali di Kecamatan Gambir, Kota Administrasi Jakarta Pusat, Provinsi DKI Jakarta akan memiliki NIK 3171011708450001 (jika laki-laki) dan 3171015708450001 (jika perempuan) di mana:

• 317101 merupakan kode Kecamatan Gambir, Kota Administrasi Jakarta Pusat, Provinsi DKI Jakarta.
• 170845 merupakan tanggal, bulan, dan tahun lahir dalam format dua digit jika laki-laki. Jika perempuan, tanggal lahir ditambahkan 40 sehingga menjadi 570845.
• 0001 merupakan nomor urut atau nomor unik saat pendaftaran.

Sehingga dengan membaca NIK, kita bisa langsung mengetahui:

• lokasi kecamatan di mana penduduk tersebut pertama kali didaftarkan,
• tanggal, bulan, dan tahun lahir dari penduduk tersebut,
• jenis kelamin dari penduduk tersebut.

Rumus Excel [.] com - NIK atau Nomor Induk Kependudukan adalah nomor identitas penduduk yang bersifat unik atau khas, tunggal dan melekat pada seseorang yang terdaftar sebagai penduduk Indonesia (wikipedia). NIK terdiri dari 16 digit yang disusun berdasarkan kode provinsi, kabupaten, kecamatan, tgl lahir dan nomor urut.

Contoh untuk NIK 3321071411180001

Dengan melihat susunan dari NIK ini, Anda bisa dengan mudah menemukan informasi jenis kelamin dan tanggal lahir dari pemilik NIK ini.

Untuk Jenis Kelamin-nya bisa di lihat dari kode tanggal pada NIK-nya jika lebih dari 40 berarti pemilik NIK tersebut adalah perempuan, jika kurang dari 40 berarti Laki-Laki.

Untuk membuat tanggal lahir dari NIK, Anda bisa menggunakan Fungsi MID.

Fungsi MID digunakan untuk mengembalikan sejumlah karakter tertentu dari suatu string teks, dimulai dari posisi yang telah ditentukan berdasarkan jumlah karakter.

Penulisan fungsinya adalah:

= MID ( text ; start_num; num_chars )

Text: merupakan teks yang membuat karakter yang ingin di ekstrak.
Start_num: merupakan posisi dari karakter pertama yang ingin di ekstrak.
Num_chars: merupakan jumlah karakter yang ingin dikembalikan.

Untuk memudahkan menghitung posisi dari karakter NIK perhatikan tabel berikut ini:

Dari tabel di atas terlihat posisi tanggal lahir ada di karakter ke 7 dan 8, posisi bulan lahir pada karakter ke 9 dan 10, sedangkan untuk tahun lahir pada posisi ke 11 dan 12.

Jadi misalnya NIK berada di sel A2 maka rumus excel untuk membuat tanggal lahir dari NIK adalah:

= MID ( A2; 7; 2)

Karena untuk tanggal ada penambahan 40 maka dari rumus menampilkan tanggal di atas, kita ubah dan tambahkan fungsi IF untuk memeriksa apakah tanggal bernilai lebih dari 40 atau bukan, jika lebih maka nilainya harus di kurangi 40 untuk menampilkan tanggalnya.

Untuk itu rumus untuk menampilkan tanggal lahirnya di ubah menjadi:

=IF(--MID(A2;7;2)>40;MID(A2;7;2)-40;MID(A2;7;2))

Fungsi IF diatas digunakan untuk memeriksa atau melakukan pengujian, apakah tanggal lahir dari NIK bernilai lebih dari 40 atau tidak, perhatikan sebelum fungsi MID yang pertama ada tanda/simbol (--) atau double unary / double negative yang fungsinya adalah untuk mengubah nilai TRUE FALSE menjadi Satu dan Nol.

Hasil Ekstrak dari fungsi MID ini berupa string atau teks sehingga akan gagal jika dilakukan pengujian dengan operator pembanding seperti (>) lebih besar dari..., karena bukan berupa angka, untuk itu sebelum MID pertama ditambahkan tanda double unary untuk mengubahnya menjadi format angka atau number.

Setelah mengetahui cara menampilkan tanggal lahir dari NIK, selanjutnya adalah menampilkan bulan lahirnya, dan rumus excel yang digunakan adalah:

=MID(A2;9;2)

Sedangkan untuk menampilkan tahun lahirnya, rumus excel yang digunakan adalah:

=IF(--MID(A2;11;2)+2000>YEAR(TODAY());19&MID(A2;11;2);20&MID(A2;11;2))

Fungsi IF disini digunakan untuk memeriksa setelah dua digit tahun dari NIK di tambah 2000 jika hasilnya lebih dari tahun sekarang, maka hasil yang ditampilkan adalah angka 19 & 2 digit tahun dari NIK, jika lebih kecil dari tahun sekarang maka yang ditampilkan adalah angka 20 & 2 digit tahun dari NIK.

Fungsi diatas akan berlaku untuk orang yang usianya maksimal 100 tahun, jika usianya lebih dari 100 tahun maka fungsi IF di atas tidak akan sesuai hasilnya.

Setelah mengetahui rumus cara mendapatkan tanggal, bulan, dan tahun lahir dari data NIK, selanjutnya adalah menggabungkan ketiga fungsi tersebut ke dalam satu sel. Agar menjadi format Date atau tanggal yang benar sebaiknya menggunakan tambahan fungsi lagi yaitu fungsi DATE.

Penulisannya adalah:

=DATE ( Tahun_Lahir; Bulan_Lahir; Tanggal_Lahir)

Sehingga rumus excel yang digunakan adalah:

=DATE(IF(--MID(A2;11;2)+2000>YEAR(TODAY());19&MID(A2;11;2);20&MID(A2;11;2)); MID(A2;9;2); IF(--MID(A2;7;2)>40;MID(A2;7;2)-40;MID(A2;7;2)))

Lampiran

Tanggal Lahir dari NIK Excel Workbook (xlsx)

Sekian tutorial tentang Rumus Excel Membuat Tanggal Lahir dari NIK, Semoga Bermanfaat...

Apakah di NIK ada tanggal lahir?

Bagaimana cara melihat NIK?

Apakah bisa Cek NIK KTP secara online?

NIK dan no KTP apakah sama?